PROGRAM 0   51 BYTES

   DPY-GUIDED FAULT ISOLATION V1.0
   STOP
   DPY-22 SEPTEMBER 1981

PROGRAM 3   18 BYTES

   EXECUTE PROGRAM 4
1: LABEL 1
   IF REGB = 40 GOTO 1

PROGRAM 4   12 BYTES

   REGB = 40
   DPY-+%B

PROGRAM 6   16 BYTES

0: LABEL 0
   INC REG1
   IF 5 > REG1 GOTO 0

PROGRAM 7   14 BYTES

   EXECUTE PROGRAM 6
   EXECUTE PROGRAM 6
   EXECUTE PROGRAM 6
   EXECUTE PROGRAM 6

PROGRAM 8   8 BYTES

   EXECUTE PROGRAM 7
   EXECUTE PROGRAM 7

PROGRAM 9   8 BYTES

   EXECUTE PROGRAM 8
   EXECUTE PROGRAM 8

PROGRAM 20   23 BYTES

   DPY-GFI CONTROL PROGRAM

PROGRAM 21   600 BYTES

   IF REGC AND FF00 = 0 GOTO E
   REG3 = REGC SHR SHR SHR SHR SHR SHR SHR SHR
   EXECUTE PROGRAM REG3
E: LABEL E
   REG3 = REG8 AND FF
   REGA = REG8 SHR SHR SHR SHR SHR SHR SHR SHR
   REG2 = REGA AND FF
   REG4 = REGA SHR SHR SHR SHR SHR SHR SHR SHR
   REG5 = 0
   REG6 = REG9 SHR SHR SHR SHR
   REG7 = REGC
   EXECUTE PROGRAM 4
   DPY-#PROBE 
   REGA = REG6
   EXECUTE PROGRAM 27
   DPY-+@2 PIN @3
   REGA = 0
   EXECUTE PROGRAM 24
   IF REGB = 40 GOTO 0
   IF 40 > REGB GOTO F
   REGB = 40
   GOTO 4
0: LABEL 0
   DPY-
   REGA = REG6
   EXECUTE PROGRAM 27
   DPY-+@2-@3 
   REGA = REG4
   EXECUTE PROGRAM 26
   REG0 = REGA
   REG1 = REGD
   REGC = REG7
   EXECUTE PROGRAM 23
   IF 40 > REGB GOTO 9
1: LABEL 1
   IF REG9 AND 2 > 0 GOTO 2
   IF REGA = REG0 GOTO 7
   GOTO 4
2: LABEL 2
   IF REG0 > REG1 GOTO 3
   IF REGA > REG1 GOTO 4
   IF REG0 > REGA GOTO 4
   GOTO 7
3: LABEL 3
   IF REG1 >= REGA GOTO 7
   IF REGA >= REG0 GOTO 7
4: LABEL 4
   IF 40 > REGB GOTO 9
   DPY-+BAD
   IF REG5 > 0 GOTO 8
   DPY-+#; LOOP?5
   IF REG5 > 0 GOTO 0
   DPY-SUSPECT BAD 
   REGC = REG7
5: LABEL 5
   REG6 = REG6 SHR SHR SHR SHR
   REG7 = REG6 AND FF
   IF REG7 = 0 GOTO 6
   REG6 = REG6 SHR SHR SHR SHR SHR SHR SHR SHR
   REGA = REG6
   EXECUTE PROGRAM 27
   DPY-+@7, 
   GOTO 5
6: LABEL 6
   DPY-+#CONT?6
   IF REG6 = 1 GOTO 9
   IF 40 > REGB GOTO A
   DPY-+%B
   GOTO A
7: LABEL 7
   DPY-+GOOD
   IF 40 > REGB GOTO 9
   IF REG5 = 0 GOTO 9
8: LABEL 8
   DPY-+;CONT
   EXECUTE PROGRAM 7
   GOTO 0
9: LABEL 9
   EXECUTE PROGRAM 9
   REGC = REG7
   IF REGB = 40 GOTO B
   IF REGB > 25 GOTO F
   IF 25 > REGB GOTO F
   REGB = 40
   IF REG5 = 0 GOTO F
   REG5 = 0
   DPY-+%B
   GOTO 1
A: LABEL A
   REGB = 1D
   GOTO F
B: LABEL B
   DPY-+%B
F: LABEL F
   REGA = 1
   EXECUTE PROGRAM 24

PROGRAM 22   1265 BYTES

   DPY-PARAMETER PACK PROGRAM#
   EXECUTE PROGRAM 9
   REGA = 0
0: LABEL 0
   DPY-DEVICE TO PROBE <1-F,ENTER>
   DPY-+ 
   EXECUTE PROGRAM 27
   EXECUTE PROGRAM 3
   REG0 = REGA
   REGA = 0
   IF REGB = 1C GOTO 1
   IF REGB = 0 GOTO 0
   IF REGB > F GOTO 0
   REGA = REGB
   GOTO 0
1: LABEL 1
   DPY-ENTER DEVICE NUMBER <256 =
   DPY-+ \7
   IF REG7 > FF GOTO 1
2: LABEL 2
   DPY-ENTER PIN NUMBER <256 = \6
   IF REG6 > FF GOTO 2
3: LABEL 3
   DPY-1ST SUSPECT TYPE <0-F,ENTER
   DPY-+> 
   EXECUTE PROGRAM 27
   EXECUTE PROGRAM 3
   REGE = REGA
   REGA = 0
   IF REGB = 1C GOTO 4
   IF REGB > F GOTO 3
   REGA = REGB
   GOTO 3
4: LABEL 4
   REG3 = 0
   IF REGE = 0 GOTO 7
   DPY-1ST SUSPECT NUMBER <256 =
   DPY-+ \3
   IF REG3 > FF GOTO 4
   REG3 = REGE SHL SHL SHL SHL SHL SHL SHL SHL OR REG3
5: LABEL 5
   IF REG3 = 0 GOTO 7
   DPY-2ND SUSPECT TYPE <0-F,ENTER
   DPY-+> 
   EXECUTE PROGRAM 27
   EXECUTE PROGRAM 3
   REGF = REGA
   REGA = 0
   IF REGB = 1C GOTO 6
   IF REGB > F GOTO 5
   REGA = REGB
   GOTO 5
6: LABEL 6
   REG2 = 0
   IF REGF = 0 GOTO 7
   DPY-2ND SUSPECT NUMBER <256 =
   DPY-+ \2
   IF REG2 > FF GOTO 6
   REG2 = REGF SHL SHL SHL SHL SHL SHL SHL SHL OR REG2
7: LABEL 7
   DPY-PRESS 0=SIG, 1=LEVEL,
   DPY-+ 2=COUNT
   EXECUTE PROGRAM 3
   REG5 = REGB
   IF REG5 > 2 GOTO 7
8: LABEL 8
   DPY-PRESS 0=FREE 1=ADRS 2=DATA
   DPY-+ SYNC
   EXECUTE PROGRAM 3
   REG4 = REGB
   IF REG4 > 2 GOTO 8
   IF REG4 > 0 GOTO 9
   IF REG5 > 0 GOTO 9
   DPY-#N0 FREE-RUN SIGNATURES
   EXECUTE PROGRAM 8
   GOTO 7
9: LABEL 9
   REG1 = 0
   REGA = 0
   DPY-SETUP PGM= \A, STIMULUS PGM
   DPY-+= \1
   IF REG1 > 63 GOTO 9
   IF REGA > 63 GOTO 9
   REG1 = REGA SHL SHL SHL SHL SHL SHL SHL SHL OR REG1
   REG8 = REG7 SHL SHL SHL SHL SHL SHL SHL SHL OR REG6
   REG9 = REG2 SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL OR REG3
   REG9 = REG9 SHL SHL SHL SHL OR REG0
   REG9 = REG9 SHL SHL OR REG4
   REG9 = REG9 SHL SHL OR REG5
   EXECUTE PROGRAM 4
   IF REGA = 0 GOTO B
   EXECUTE PROGRAM REGA
B: LABEL B
   DPY-
   REGA = REG0
   EXECUTE PROGRAM 27
   DPY-+@7-@6 
   REGA = 0
   EXECUTE PROGRAM 26
   REGC = REG1
   EXECUTE PROGRAM 23
   DPY-+CONT
   EXECUTE PROGRAM 9
   IF REGB = 1D GOTO 7
   IF REGB = 40 GOTO B
C: LABEL C
   REGD = REGA
   REG6 = REGD AND 7F
   REG7 = REG6
   IF REG5 = 2 GOTO E
   REG7 = 0
   REG6 = REGD AND FFFF
   IF REG5 = 0 GOTO D
   REG6 = REGD SHR SHR SHR SHR SHR SHR SHR SHR SHR SHR SHR SHR SHR SHR SHR SHR 
SHR SHR SHR SHR SHR SHR SHR SHR AND 7
   DPY-ENTER LVL <4,2,1=L,X,H> $6
   DPY-+ = /6
   IF REG6 > 7 GOTO C
   REG6 = REG6 SHL SHL SHL SHL SHL SHL SHL SHL
   GOTO F
D: LABEL D
   DPY-ENTER SIGNATURE $6 = /6
   IF REG6 > FFFF GOTO D
   GOTO F
E: LABEL E
   DPY-ENTER COUNT MIN $6=/6
   DPY-+, MAX $7=/7
   IF REG6 > 7F GOTO E
   IF REG7 > 7F GOTO E
   REG6 = REG6 SHL SHL SHL SHL SHL SHL SHL SHL
F: LABEL F
   REG8 = REG6 SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL 
OR REG8
   REG8 = REG7 SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL SHL 
OR REG8
   REGC = REG1
   DPY-REG C=$C; 8=$8; 9=$9
   AUX-REG C=$C;  8=$8;  9=$9
   EXECUTE PROGRAM 3
   REGA = 0
   SYNC FREE-RUN
   GOTO 0

PROGRAM 23   224 BYTES

   REG1 = REGD
   IF REG9 AND C = C GOTO D
   IF REG9 AND 3 = 3 GOTO D
   REG2 = REGC AND FF
0: LABEL 0
   SYNC DATA
   IF REG9 AND 8 > 0 GOTO 1
   SYNC ADDRESS
   IF REG9 AND 4 > 0 GOTO 1
   IF REG9 AND 3 = 0 GOTO 1
   SYNC FREE-RUN
1: LABEL 1
   READ PROBE
   READ PROBE
   IF REG2 = 0 GOTO 2
   EXECUTE PROGRAM REG2
   READ PROBE
2: LABEL 2
   IF REG9 AND 2 > 0 GOTO 3
   IF REG9 AND 1 > 0 GOTO 4
   REGA = REG0 SHR SHR SHR SHR SHR SHR SHR SHR AND FFFF
   DPY-+$A
   GOTO E
3: LABEL 3
   REGA = REG0 AND 7F
   DPY-+$AH
   GOTO E
4: LABEL 4
   REGA = REG0 AND 7000000
   EXECUTE PROGRAM 25
   GOTO E
D: LABEL D
   DPY-+#BAD REG9=$9
   STOP
E: LABEL E
   DPY-+, 
F: LABEL F
   REGD = REG1

PROGRAM 24   236 BYTES

   SYNC FREE-RUN
   IF REGA > 0 GOTO 0
   IF REG9 AND 1 = 0 GOTO 0
   IF REG8 AND 7000000 = 2000000 GOTO 4
0: LABEL 0
   REG1 = 10
1: LABEL 1
   READ PROBE
   IF REGA = 0 GOTO 2
   IF REG0 AND 5000000 = 0 GOTO 3
   DPY-REMOVE PROBE
   GOTO 0
2: LABEL 2
   IF 40 > REGB GOTO D
   IF REG0 AND 5000000 = 0 GOTO 0
3: LABEL 3
   DEC REG1
   IF 40 > REGB GOTO F
   IF REG1 > 0 GOTO 1
   GOTO F
4: LABEL 4
   DPY-+, CONTINUE
5: LABEL 5
   IF REGB = 40 GOTO 5
   IF REGB = 25 GOTO 6
   GOTO F
6: LABEL 6
   EXECUTE PROGRAM 4
   GOTO F
D: LABEL D
   IF 25 > REGB GOTO F
   IF REGB > 25 GOTO F
   EXECUTE PROGRAM 4
   REGB = 41
   DPY-+ 
F: LABEL F

PROGRAM 25   74 BYTES

   IF REGA AND 1000000 = 0 GOTO 1
   DPY-+H
1: LABEL 1
   IF REGA AND 2000000 = 0 GOTO 2
   DPY-+X
2: LABEL 2
   IF REGA AND 4000000 = 0 GOTO 3
   DPY-+L
3: LABEL 3

PROGRAM 26   120 BYTES

   IF REG9 AND 1 = 1 GOTO 2
   IF REG9 AND 2 = 2 GOTO 3
1: LABEL 1
   DPY-+SIG $A
   GOTO 4
2: LABEL 2
   REGA = REG8 AND 7000000
   DPY-+LEVEL 
   EXECUTE PROGRAM 25
   GOTO 4
3: LABEL 3
   REGD = REGA AND 7F
   REGA = REGA SHR SHR SHR SHR SHR SHR SHR SHR AND 7F
   DPY-+CNT $A-$D
4: LABEL 4
   DPY-+= 

PROGRAM 27   284 BYTES

   REG1 = REGA AND F
   IF REG1 = 0 GOTO F
   IF REG1 = 1 GOTO 1
   IF REG1 = 2 GOTO 2
   IF REG1 = 3 GOTO 3
   IF REG1 = 4 GOTO 4
   IF REG1 = 5 GOTO 5
   IF REG1 = 6 GOTO 6
   IF REG1 = 7 GOTO 7
   IF REG1 = 8 GOTO 8
   IF REG1 = 9 GOTO 9
   IF REG1 = A GOTO A
   IF REG1 = B GOTO B
   IF REG1 = C GOTO C
   IF REG1 = D GOTO D
   IF REG1 = E GOTO E
   DPY-+
   GOTO F
1: LABEL 1
   DPY-+U
   GOTO F
2: LABEL 2
   DPY-+Q
   GOTO F
3: LABEL 3
   DPY-+R
   GOTO F
4: LABEL 4
   DPY-+C
   GOTO F
5: LABEL 5
   DPY-+CR
   GOTO F
6: LABEL 6
   DPY-+SW
   GOTO F
7: LABEL 7
   DPY-+LED
   GOTO F
8: LABEL 8
   DPY-+KEY
   GOTO F
9: LABEL 9
   DPY-+K
   GOTO F
A: LABEL A
   DPY-+P
   GOTO F
B: LABEL B
   DPY-+J
   GOTO F
C: LABEL C
   DPY-+X
   GOTO F
D: LABEL D
   DPY-+BP
   GOTO F
E: LABEL E
   DPY-+
   GOTO F
F: LABEL F